source: subversion/applications/editors/potlatch/world.as @ 14664

Last change on this file since 14664 was 14664, checked in by richard, 10 years ago

be a bit more economical with initial whichways

File size: 8.8 KB
Line 
1
2        // =====================================================================================
3        // Potlatch co-ordinate handling
4
5        // updateCoords - update all co-ordinate global variables
6
7        function updateCoords(tx,ty) {
8                _root.bscale=Math.pow(2,_root.scale-13);
9                _root.xradius=Stage.width/2;
10                _root.yradius=(Stage.height-panelheight)/2;
11
12                _root.map._x=tx; _root.map._y=ty;
13                _root.map._xscale=100*bscale;
14                _root.map._yscale=100*bscale;
15
16                _root.edge_t=coord2lat ((-_root.map._y          )/bscale); _root.tile_t=lat2tile (edge_t);
17                _root.edge_b=coord2lat ((-_root.map._y+2*yradius)/bscale); _root.tile_b=lat2tile (edge_b);
18                _root.edge_l=coord2long((-_root.map._x          )/bscale); _root.tile_l=long2tile(edge_l);
19                _root.edge_r=coord2long((-_root.map._x+2*xradius)/bscale); _root.tile_r=long2tile(edge_r);
20
21                _root.tile_t=lat2tile (coord2lat ((-_root.bgyoffset-_root.map._y          )/bscale));
22                _root.tile_b=lat2tile (coord2lat ((-_root.bgyoffset-_root.map._y+2*yradius)/bscale));
23                _root.tile_l=long2tile(coord2long((-_root.bgxoffset-_root.map._x          )/bscale));
24                _root.tile_r=long2tile(coord2long((-_root.bgxoffset-_root.map._x+2*xradius)/bscale));
25        }
26
27        // lat/long <-> coord conversion
28
29        function lat2coord(a)   { return -(lat2y(a)-basey)*masterscale; }
30        function coord2lat(a)   { return y2lat(a/-masterscale+basey); }
31        function long2coord(a)  { return (a-baselong)*masterscale; }
32        function coord2long(a)  { return a/masterscale+baselong; }
33        function y2lat(a) { return 180/Math.PI * (2 * Math.atan(Math.exp(a*Math.PI/180)) - Math.PI/2); }
34        function lat2y(a) { return 180/Math.PI * Math.log(Math.tan(Math.PI/4+a*(Math.PI/180)/2)); }
35        function centrelat(o)  { return  coord2lat((yradius-_root.map._y-o)/Math.pow(2,_root.scale-13)); }
36        function centrelong(o) { return coord2long((xradius-_root.map._x-o)/Math.pow(2,_root.scale-13)); }
37
38        // resizeWindow - user has enlarged/shrunk window
39
40        function resizeWindow() {
41                setSizes();
42                updateCoords(_root.map._x,_root.map._y);
43                _root.lastresize=new Date();
44        }
45
46        function setSizes() {
47                // resize Yahoo
48                clearInterval(_root.yahooresizer);
49                if (_root.yahooinited) {
50                        setYahooSize();
51                        _root.ylat=centrelat(_root.bgyoffset);
52                        _root.ylon=centrelong(_root.bgxoffset);
53                        repositionYahoo(true);
54                }
55                // resize main mask and panel
56                _root.masksquare._height=
57                _root.panel._y=Stage.height-panelheight;
58                _root.masksquare._width=Stage.width;
59                // resize panel window
60                if (_root.panel.properties.proptype!='') {
61                        _root.panel.properties.init(_root.panel.properties.proptype,getPanelColumns(),4);
62                }
63                _root.panel.i_repeatattr._x=
64                _root.panel.i_newattr._x=
65                _root.panel.i_newrel._x=120+getPanelColumns()*190;
66                // resize other stuff
67                _root.waysloading._x=
68                _root.tooltip._x=Stage.width-220;
69                setStatusPosition();
70                for (var w in _root.windows) {
71                        if (typeof(_root.windows[w])=='movieclip') { _root.windows[w].drawAreas(); }
72                }
73        }
74
75        function setYahooSize() {
76                if (_root.yahoowidth!=Stage.width || _root.yahooheight!=Stage.height-panelheight) {
77                        _root.yahoowidth=Stage.width;
78                        _root.yahooheight=Stage.height-panelheight;
79                        _root.yahoo.myMap.setSize(yahoowidth,yahooheight);
80                }
81                _root.yahoorightsize=true;
82        }
83
84        // updateLinks - update view/edit tabs
85
86        function updateLinks() {
87//              if (winie) { fscommand("maplinks",centrelong(0),centrelat(0),_root.scale); } else {
88                getURL("javascript:updatelinks("+centrelong(0)+","+centrelat(0)+","+_root.scale+")");
89        }
90       
91        // maximiseSWF - call JavaScript to maximise/minimise
92       
93        function maximiseSWF() {
94                if (_root.maximised) { getURL("javascript:minimiseMap()"); }
95                                                else { getURL("javascript:maximiseMap()"); }
96                _root.maximised=!_root.maximised;
97        }
98
99        // =====================================================================================
100        // Zoom
101
102        // zoomIn, zoomOut, changeScaleTo - change scale functions
103       
104        function zoomIn() {
105                if (_root.scale<_root.maxscale) {
106                        if (_root.waycount>500) { purgeWays(); }
107                        if (_root.poicount>500) { purgePOIs(); }
108                        zoomTo(_root.scale+1,_root.map._x*2-xradius,_root.map._y*2-yradius,false);
109                }
110        }
111       
112        function zoomOut() {
113                if (_root.scale>_root.minscale) {
114                        zoomTo(_root.scale-1,(_root.map._x+xradius)/2,(_root.map._y+yradius)/2,true);
115                }
116        }
117
118        function zoomTo(newscale,newx,newy,ww) {
119                var oldwidth=linewidth;
120                blankTileQueue();
121                changeScaleTo(newscale);
122                updateCoords(newx,newy);
123                updateLinks();
124                redrawBackground();
125                resizePOIs();
126                if (ww) { whichWays(); }
127                else if (_root.waycount>500) { purgeWays(); }
128                redrawWays(oldwidth==linewidth);
129        }
130
131        function changeScaleTo(newscale) {
132                _root.map.tiles[_root.scale]._visible=false; _root.scale=newscale;
133                _root.map.tiles[_root.scale]._visible=true;
134                if (_root.scale==_root.minscale) { _root.i_zoomout._alpha=25;  }
135                                                                        else { _root.i_zoomout._alpha=100; }
136                if (_root.scale==_root.maxscale) { _root.i_zoomin._alpha =25;  }
137                                                                        else { _root.i_zoomin._alpha =100; }
138                _root.tolerance=4/Math.pow(2,_root.scale-13);
139                if (preferences.data.thinlines) {
140                        _root.linewidth=3;
141                        _root.taggedscale=100/Math.pow(2,_root.scale-13); 
142                } else {
143                        _root.linewidth=3+Math.pow(Math.max(0,_root.scale-15),2);
144                        _root.taggedscale=Math.max(100/Math.pow(2,_root.scale-13),10);
145                        if (_root.scale==16 || _root.scale==17) { _root.taggedscale*=1.3; }
146                }
147        }
148
149        function redrawWays(skip) {
150                if (_root.wayselected) {
151                        _root.ws.redraw();
152                        _root.ws.highlight();
153                        _root.ws.highlightPoints(5000,"anchor");
154                }
155                restartElastic();
156                _root.redrawlist=new Array();
157                if (_root.redrawskip) { _root.redrawskip=skip; }
158                for (var qway in _root.map.ways) { _root.redrawlist.push(qway); }
159        }
160
161        // =====================================================================================
162        // Backgrounds
163
164        function initBackground() {
165                preferences.flush();
166                _root.bgxoffset=0; _root.bgyoffset=0;
167                setStatusPosition();
168                redrawBackground(); 
169        }
170
171        function redrawBackground() {
172                var alpha=100-50*preferences.data.dimbackground;
173                switch (preferences.data.bgtype) {
174                        case 4: // No background
175                                        _root.yahoo._visible=false;
176                                        _root.map.tiles._visible=false;
177                                        break;
178                                       
179                        case 2: // Yahoo
180                                        _root.yahoo._visible=true;
181                                        _root.yahoo._alpha=alpha;       
182                                        _root.yahoo._x=0; _root.yahoo._y=0;
183                                        _root.ylat=centrelat(_root.bgyoffset);
184                                        _root.ylon=centrelong(_root.bgxoffset);
185                                        _root.yzoom=18-_root.scale;
186                                        _root.map.tiles._visible=false;
187                                        if     (!_root.yahooloaded) { loadMovie(yahoourl,_root.yahoo);
188                                                                                                  _root.yahooloaded=true;
189                                                                                                  _root.yahoo.swapDepths(_root.masksquare); }
190                                        else if (_root.yahooinited) { repositionYahoo(true); }
191                                        break;
192
193                        default: // Tiles
194                                        if (_root.tilesetloaded!=preferences.data.tilecustom+'/'+preferences.data.bgtype+'/'+preferences.data.tileset) {
195                                                _root.tilesetloaded=preferences.data.tilecustom+'/'+preferences.data.bgtype+'/'+preferences.data.tileset;
196                                                initTiles();
197                                        }
198                                        _root.map.tiles._visible=true;
199                                        _root.map.tiles._alpha=alpha;
200                                        _root.yahoo._visible=false;
201                                        updateTiles();
202                                        break;
203                }
204        }
205
206        function repositionYahoo(force) {
207                clearInterval(_root.yahooresizer);
208                if (!_root.yahooinited) { return; }
209                pos=_root.yahoo.myMap.getCenter();
210                if (pos) {
211                        pos.lat=_root.ylat;
212                        pos.lon=_root.ylon;
213                        if (_root.lastyzoom!=_root.yzoom) {
214                                _root.yahoo.myMap.setCenterByLatLonAndZoom(pos,_root.yzoom,0);
215                        } else if (_root.lastylat!=_root.ylat || _root.lastylon!=_root.ylon || force) {
216                                _root.yahoo.myMap.setCenterByLatLon(pos,0);
217                        }
218                        clearInterval(_root.copyrightID);
219                        _root.copyrightID=setInterval(refreshYahooCopyright,1000);
220                        _root.lastyzoom=_root.yzoom;
221                        _root.lastylon =_root.ylon;
222                        _root.lastylat =_root.ylat;
223                }
224        }
225
226        function refreshYahooCopyright() {
227                clearInterval(_root.copyrightID);
228                _root.yahoo.myMap.map.updateCopyright();
229        };
230
231        function enableYahooZoom() {
232                b=_global.com.yahoo.maps.projections.Projection.prototype;
233                ASSetPropFlags(b,null,0,true);
234                b.MAXLEVEL=20;
235       
236                b=_global.com.yahoo.maps.projections.MercatorProjection.prototype;
237                ASSetPropFlags(b,null,0,true);
238       
239                b.ll_to_pxy = function (lat, lon) {
240                        var ys=18-_root.scale;
241                        var cp=1 << 26 - ys;
242                        this.level_=ys;
243                        this.ntiles_w_ = cp / this.tile_w_;
244                        this.ntiles_h_ = cp / this.tile_h_;
245                        this.meters_per_pixel_ = 111111*360 / cp;
246                        this.x_per_lon_ = cp / 360;
247                       
248                        alat = Math.abs(lat);
249                        alon = lon + 180;
250                        v_pxy = new this.PixelXY();
251                        if (alat >= 90 || alon > 360 || alon < 0) {
252                                return v_pxy;
253                        }
254                        alat *= this.RAD_PER_DEG;
255                        v_pxy.m_x = alon * this.x_per_lon_;
256                        ytemp = Math.log(Math.tan(alat) + 1 / Math.cos(alat)) / Math.PI;
257                        v_pxy.m_y = ytemp * this.pixel_height() / 2;
258                        if (lat < 0) {
259                                v_pxy.m_y = -v_pxy.m_y;
260                        }
261                        this.status_ = 1;
262                        return v_pxy;
263                };
264       
265                b=_global.com.yahoo.maps.flash.ExtensibleTileUrl.prototype;
266                ASSetPropFlags(b,null,0,true);
267       
268                b.makeUrl = function (row, col, mapViewType) {
269                  return this.satelliteUrl + '&x=' + col + '&y=' + row + '&z=' + String(19-this.zoom) + '&r=1&v=' + this.satelliteBatch + '&t=a';
270                };
271        }
Note: See TracBrowser for help on using the repository browser.