source: subversion/applications/editors/potlatch/world.as @ 16865

Last change on this file since 16865 was 16865, checked in by richard, 10 years ago

Potlatch 1.2

File size: 9.9 KB
Line 
1
2        // =====================================================================================
3        // Potlatch co-ordinate handling
4
5        // updateCoords - update all co-ordinate global variables
6
7        function updateCoords(tx,ty) {
8                _root.bscale=Math.pow(2,_root.scale-13);
9                _root.xradius=Stage.width/2;
10                _root.yradius=(Stage.height-panelheight)/2;
11
12                _root.map._x=tx; _root.map._y=ty;
13                _root.map._xscale=100*bscale;
14                _root.map._yscale=100*bscale;
15
16                _root.edge_t=coord2lat ((-_root.map._y          )/bscale); _root.tile_t=lat2tile (edge_t);
17                _root.edge_b=coord2lat ((-_root.map._y+2*yradius)/bscale); _root.tile_b=lat2tile (edge_b);
18                _root.edge_l=coord2long((-_root.map._x          )/bscale); _root.tile_l=long2tile(edge_l);
19                _root.edge_r=coord2long((-_root.map._x+2*xradius)/bscale); _root.tile_r=long2tile(edge_r);
20
21                _root.tile_t=lat2tile (coord2lat ((-_root.bgyoffset-_root.map._y          )/bscale));
22                _root.tile_b=lat2tile (coord2lat ((-_root.bgyoffset-_root.map._y+2*yradius)/bscale));
23                _root.tile_l=long2tile(coord2long((-_root.bgxoffset-_root.map._x          )/bscale));
24                _root.tile_r=long2tile(coord2long((-_root.bgxoffset-_root.map._x+2*xradius)/bscale));
25               
26                if (_root.panel.scale._visible) { setTypeText('',''); }
27        }
28
29        // lat/long <-> coord conversion
30
31        function lat2coord(a)   { return -(lat2y(a)-basey)*masterscale; }
32        function coord2lat(a)   { return y2lat(a/-masterscale+basey); }
33        function long2coord(a)  { return (a-baselong)*masterscale; }
34        function coord2long(a)  { return a/masterscale+baselong; }
35        function y2coord(a)             { return (a-basey)*-masterscale; }
36        function coord2y(a)             { return a/-masterscale+basey; }
37        function y2lat(a) { return 180/Math.PI * (2 * Math.atan(Math.exp(a*Math.PI/180)) - Math.PI/2); }
38        function lat2y(a) { return 180/Math.PI * Math.log(Math.tan(Math.PI/4+a*(Math.PI/180)/2)); }
39        function centrelat(o)  { return  coord2lat((yradius-_root.map._y-o)/Math.pow(2,_root.scale-13)); }
40        function centrelong(o) { return coord2long((xradius-_root.map._x-o)/Math.pow(2,_root.scale-13)); }
41
42        // resizeWindow - user has enlarged/shrunk window
43
44        function resizeWindow() {
45                setSizes();
46                updateCoords(_root.map._x,_root.map._y);
47                _root.lastresize=new Date();
48        }
49
50        function setSizes() {
51                // resize Yahoo
52                clearInterval(_root.yahooresizer);
53                if (_root.yahooinited) {
54                        setYahooSize();
55                        _root.ylat=centrelat(_root.bgyoffset);
56                        _root.ylon=centrelong(_root.bgxoffset);
57                        repositionYahoo(true);
58                }
59                // resize main mask and panel
60                _root.masksquare._height=
61                _root.panel._y=Stage.height-panelheight;
62                _root.masksquare._width=Stage.width;
63                // resize panel window
64                if (_root.panel.properties.proptype!='') {
65                        _root.panel.properties.init(_root.panel.properties.proptype,getPanelColumns(),4);
66                } else {
67                        drawIconPanel();
68                }
69                _root.panel.i_repeatattr._x=
70                _root.panel.i_newattr._x=
71                _root.panel.i_newrel._x=120+getPanelColumns()*190;
72                // resize other stuff
73                _root.waysloading._x=
74                _root.tooltip._x=Stage.width-220;
75                setStatusPosition();
76                for (var w in _root.windows) {
77                        if (typeof(_root.windows[w])=='movieclip') { _root.windows[w].drawAreas(); }
78                }
79        }
80
81        function setYahooSize() {
82                if (_root.yahoowidth!=Stage.width || _root.yahooheight!=Stage.height-panelheight) {
83                        _root.yahoowidth=Stage.width;
84                        _root.yahooheight=Stage.height-panelheight;
85                        _root.yahoo.myMap.setSize(yahoowidth,yahooheight);
86                }
87                _root.yahoorightsize=true;
88        }
89
90        // updateLinks - update view/edit tabs
91
92        function updateLinks() {
93                if (winie) {
94                        if (gpx) { flash.external.ExternalInterface.call("updatelinks",centrelong(0),centrelat(0),_root.scale,'',_root.edge_l,_root.edge_b,_root.edge_r,_root.edge_t,'gpx',gpx); }
95                                else { flash.external.ExternalInterface.call("updatelinks",centrelong(0),centrelat(0),_root.scale,'',_root.edge_l,_root.edge_b,_root.edge_r,_root.edge_t); }
96                } else {
97                        var url="javascript:updatelinks("+centrelong(0)+","+centrelat(0)+","+_root.scale+",'',"+_root.edge_l+","+_root.edge_b+","+_root.edge_r+","+_root.edge_t;
98                        if (gpx) { url+=",'gpx',"+gpx; }
99                        url=url+")"; getURL(url);
100                }
101        }
102       
103        // maximiseSWF - call JavaScript to maximise/minimise
104       
105        function maximiseSWF() {
106                if (_root.maximised) { getURL("javascript:minimiseMap()"); _root.panel.advanced.renameOption(6,iText("Maximise window","advanced_maximise")); }
107                                                else { getURL("javascript:maximiseMap()"); _root.panel.advanced.renameOption(6,iText("Minimise window","advanced_minimise")); }
108                _root.maximised=!_root.maximised;
109        }
110
111        // =====================================================================================
112        // Zoom
113
114        // zoomIn, zoomOut, changeScaleTo - change scale functions
115       
116        function zoomIn() {
117                if (_root.scale<_root.maxscale) {
118                        if (_root.waycount>500) { purgeWays(); }
119                        if (_root.poicount>500) { purgePOIs(); }
120                        zoomTo(_root.scale+1,_root.map._x*2-xradius,_root.map._y*2-yradius,false);
121                }
122        }
123       
124        function zoomOut() {
125                if (_root.scale>_root.minscale) {
126                        zoomTo(_root.scale-1,(_root.map._x+xradius)/2,(_root.map._y+yradius)/2,true);
127                }
128        }
129
130        function zoomTo(newscale,newx,newy,ww) {
131                var oldwidth=linewidth;
132                blankTileQueue();
133                changeScaleTo(newscale);
134                updateCoords(newx,newy);
135                updateLinks();
136                redrawBackground();
137                resizePOIs();
138                if (ww) { whichWays(); }
139                else if (_root.waycount>500) { purgeWays(); }
140                redrawWays(oldwidth==linewidth);
141        }
142
143        function changeScaleTo(newscale) {
144                _root.map.tiles[_root.scale]._visible=false; _root.scale=newscale;
145                _root.map.tiles[_root.scale]._visible=true;
146                if (_root.scale==_root.minscale) { _root.i_zoomout._alpha=25;  }
147                                                                        else { _root.i_zoomout._alpha=100; }
148                if (_root.scale==_root.maxscale) { _root.i_zoomin._alpha =25;  }
149                                                                        else { _root.i_zoomin._alpha =100; }
150                _root.tolerance=4/Math.pow(2,_root.scale-13);
151                _root.poiscale=Math.max(100/Math.pow(2,_root.scale-13),3);
152                _root.iconscale=100/Math.pow(2,_root.scale-13);
153                if (preferences.data.thinlines) {
154                        _root.linewidth=3;
155                        _root.taggedscale=100/Math.pow(2,_root.scale-13); 
156                } else {
157                        _root.linewidth=Math.min(10, 3+Math.pow(Math.max(0,_root.scale-15),2));
158                        _root.taggedscale=Math.max(100/Math.pow(2,_root.scale-13),5);
159                        if (_root.scale>=16 && _root.scale<=18) { _root.taggedscale*=1.3; }
160                        if (_root.scale>=17 && _root.scale<=18) { _root.poiscale   *=1.3; }
161                }
162                if (preferences.data.thinareas) { _root.areawidth=_root.linewidth/3; }
163                                                                   else { _root.areawidth=_root.linewidth; }
164        }
165
166        function redrawWays(skip) {
167                if (_root.wayselected) {
168                        _root.ws.redraw();
169                        _root.ws.highlight();
170                        _root.ws.highlightPoints(5000,"anchor");
171                }
172                restartElastic();
173                _root.redrawlist=new Array();
174                if (_root.redrawskip) { _root.redrawskip=skip; }
175                for (var qway in _root.map.ways) { _root.redrawlist.push(qway); }
176        }
177
178        // =====================================================================================
179        // Backgrounds
180
181        function initBackground() {
182                preferences.flush();
183                _root.bgxoffset=0; _root.bgyoffset=0;
184                setStatusPosition();
185                redrawBackground(); 
186        }
187
188        function redrawBackground() {
189                var alpha=100-50*preferences.data.dimbackground;
190                switch (preferences.data.bgtype) {
191                        case 4: // No background
192                                        _root.yahoo._visible=false;
193                                        _root.map.tiles._visible=false;
194                                        break;
195                                       
196                        case 2: // Yahoo
197                                        _root.yahoo._visible=true;
198                                        _root.yahoo._alpha=alpha;       
199                                        _root.yahoo._x=0; _root.yahoo._y=0;
200                                        _root.ylat=centrelat(_root.bgyoffset);
201                                        _root.ylon=centrelong(_root.bgxoffset);
202                                        _root.yzoom=18-_root.scale;
203                                        _root.map.tiles._visible=false;
204                                        if     (!_root.yahooloaded) { loadMovie(yahoourl,_root.yahoo);
205                                                                                                  _root.yahooloaded=true;
206                                                                                                  _root.yahoo.swapDepths(_root.masksquare); }
207                                        else if (_root.yahooinited) { repositionYahoo(true); }
208                                        break;
209
210                        default: // Tiles
211                                        if (_root.tilesetloaded!=preferences.data.tilecustom+'/'+preferences.data.bgtype+'/'+preferences.data.tileset) {
212                                                _root.tilesetloaded=preferences.data.tilecustom+'/'+preferences.data.bgtype+'/'+preferences.data.tileset;
213                                                initTiles();
214                                        }
215                                        _root.map.tiles._visible=true;
216                                        _root.map.tiles._alpha=alpha;
217                                        _root.yahoo._visible=false;
218                                        updateTiles();
219                                        break;
220                }
221        }
222
223        function repositionYahoo(force) {
224                clearInterval(_root.yahooresizer);
225                if (!_root.yahooinited) { return; }
226                pos=_root.yahoo.myMap.getCenter();
227                if (pos) {
228                        pos.lat=_root.ylat;
229                        pos.lon=_root.ylon;
230                        if (_root.lastyzoom!=_root.yzoom) {
231                                _root.yahoo.myMap.setCenterByLatLonAndZoom(pos,_root.yzoom,0);
232                        } else if (_root.lastylat!=_root.ylat || _root.lastylon!=_root.ylon || force) {
233                                _root.yahoo.myMap.setCenterByLatLon(pos,0);
234                        }
235                        clearInterval(_root.copyrightID);
236                        _root.copyrightID=setInterval(refreshYahooCopyright,1000);
237                        _root.lastyzoom=_root.yzoom;
238                        _root.lastylon =_root.ylon;
239                        _root.lastylat =_root.ylat;
240                }
241        }
242
243        function refreshYahooCopyright() {
244                clearInterval(_root.copyrightID);
245                _root.yahoo.myMap.map.updateCopyright();
246        };
247
248        function enableYahooZoom() {
249                b=_global.com.yahoo.maps.projections.Projection.prototype;
250                ASSetPropFlags(b,null,0,true);
251                b.MAXLEVEL=20;
252       
253                b=_global.com.yahoo.maps.projections.MercatorProjection.prototype;
254                ASSetPropFlags(b,null,0,true);
255       
256                b.ll_to_pxy = function (lat, lon) {
257                        var ys=18-_root.scale;
258                        var cp=1 << 26 - ys;
259                        this.level_=ys;
260                        this.ntiles_w_ = cp / this.tile_w_;
261                        this.ntiles_h_ = cp / this.tile_h_;
262                        this.meters_per_pixel_ = 111111*360 / cp;
263                        this.x_per_lon_ = cp / 360;
264                       
265                        alat = Math.abs(lat);
266                        alon = lon + 180;
267                        v_pxy = new this.PixelXY();
268                        if (alat >= 90 || alon > 360 || alon < 0) {
269                                return v_pxy;
270                        }
271                        alat *= this.RAD_PER_DEG;
272                        v_pxy.m_x = alon * this.x_per_lon_;
273                        ytemp = Math.log(Math.tan(alat) + 1 / Math.cos(alat)) / Math.PI;
274                        v_pxy.m_y = ytemp * this.pixel_height() / 2;
275                        if (lat < 0) {
276                                v_pxy.m_y = -v_pxy.m_y;
277                        }
278                        this.status_ = 1;
279                        return v_pxy;
280                };
281       
282                b=_global.com.yahoo.maps.flash.ExtensibleTileUrl.prototype;
283                ASSetPropFlags(b,null,0,true);
284       
285                b.makeUrl = function (row, col, mapViewType) {
286                  return this.satelliteUrl + '&x=' + col + '&y=' + row + '&z=' + String(19-this.zoom) + '&r=1&v=' + this.satelliteBatch + '&t=a';
287                };
288        }
Note: See TracBrowser for help on using the repository browser.